infra/flake.nix

{
  description = "Gortium infra flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    agenix = {
      url = "github:ryantm/agenix";
      inputs.darwin.follows = "";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    lix = {
      url = "git+https://git.lix.systems/lix-project/lix?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # uConsole CM5 — pinned nixpkgs for kernel patch compatibility
    nixpkgs-uconsole.url = "github:NixOS/nixpkgs/nixos-25.11";
    nixos-uconsole = {
      url = "github:nixos-uconsole/nixos-uconsole/v1.1.0";
      inputs.nixpkgs.follows = "nixpkgs-uconsole";
      inputs.nixos-raspberrypi.follows = "nixos-raspberrypi";
    };
    nixos-raspberrypi = {
      url = "github:gortium/nixos-raspberrypi/cm5-cross-v1";
      inputs.nixpkgs.follows = "nixpkgs-uconsole";
    };
    self.submodules = true;
  };

  outputs = { self, nixpkgs, agenix, lix
            , nixpkgs-uconsole, nixos-uconsole, nixos-raspberrypi
            , ... }@inputs:
    let
      system = "x86_64-linux";
      keys = import ./lib/keys.nix;
      paths = {
        flake = "/home/gortium/infra";
        identities = [
          "/home/gortium/.ssh/gortium_ssh_key"
          "/etc/ssh/ssh_host_ed25519_key"
          "/root/.age/bootstrap.key" ];
      };
      overlays = [ agenix.overlays.default ];
      pkgs = import nixpkgs {
        inherit system overlays;
        config.allowUnfree = true;
        config.permittedInsecurePackages = [
          "openclaw-2026.3.12"
        ];
      };

      devShell = import ./shells/nix_dev.nix {
        inherit pkgs system agenix;
      };
    in
      {
        nixosConfigurations = {
          lazyworkhorse = nixpkgs.lib.nixosSystem {
            specialArgs = { inherit system self keys paths inputs; };
            modules = [
              {
                nixpkgs.overlays = overlays;
                nixpkgs.config.allowUnfree = true;
                nixpkgs.config.rocmSupport = true;
                nixpkgs.config.permittedInsecurePackages = [
                  "openclaw-2026.3.12"
                ];
                nix.package = lix.packages.${system}.default;
              }
              agenix.nixosModules.default
              ./hosts/lazyworkhorse/configuration.nix
              ./hosts/lazyworkhorse/hardware-configuration.nix
              ./modules/nixos/filesystem/hoardingcow-mount.nix
              ./modules/nixos/services/docker_manager.nix
              ./modules/nixos/services/open_code_server.nix
              ./modules/nixos/services/ollama_init_custom_models.nix
              ./modules/nixos/services/openclaw_node.nix
              ./modules/nixos/security/ai-worker-restricted.nix
              ./users/gortium.nix
              ./users/ai-worker.nix
            ];
          };

          cyt-pi = nixpkgs.lib.nixosSystem {
            specialArgs = { inherit self keys paths inputs; };
            modules = [
              {
                nixpkgs.overlays = overlays;
                nixpkgs.config.allowUnfree = true;
                nixpkgs.hostPlatform = "aarch64-linux";
                nix.package = lix.packages."aarch64-linux".default;
              }
              ./hosts/cyt-pi/configuration.nix
              ./hosts/cyt-pi/hardware-configuration.nix
            ];
          };

          # ============================================================
          # uConsole CM5 — cross-compilé (build sur x86_64, run sur ARM)
          # Approche incrémentale pour fixer l'écran
          # ============================================================
          uconsole-cm5 = nixpkgs-uconsole.lib.nixosSystem {
            system = "aarch64-linux";
            specialArgs = {
              inherit self keys paths inputs;
              nixos-raspberrypi = nixos-raspberrypi;
              isCM4 = false;
            };
            modules = [
              {
                # Cross-compile : build sur x86_64, run sur aarch64
                nixpkgs.buildPlatform = "x86_64-linux";
                nixpkgs.hostPlatform = "aarch64-linux";
                nixpkgs.config.allowUnfree = true;
                boot.loader.raspberry-pi.bootloader = "kernel";
              }
              # nixos-raspberrypi — pkgs.rpi + overlays standardisés
              nixos-raspberrypi.nixosModules.nixpkgs-rpi
              nixos-raspberrypi.nixosModules.raspberry-pi-5.base
              nixos-raspberrypi.lib.inject-overlays
              nixos-raspberrypi.lib.inject-overlays-global
              # nixos-uconsole CM5 modules
              nixos-uconsole.nixosModules.kernel
              nixos-uconsole.nixosModules.configtxt
              (nixos-uconsole.nixosModules.cm { lib = nixpkgs-uconsole.lib; isCM4 = false; })
              nixos-uconsole.nixosModules.base
              # Lix cross-compilé (lix.packages.aarch64-linux est natif → QEMU)
              ({ config, lib, pkgs, inputs, ... }: let
                lix-cross = import inputs.nixpkgs-uconsole {
                  localSystem = { system = "x86_64-linux"; };
                  crossSystem = { system = "aarch64-linux"; };
                  overlays = [ inputs.lix.overlays.default ];
                };
              in { nix.package = lix-cross.lix; })
              # agenix
              agenix.nixosModules.default
              # Notre config
              ./hosts/uconsole-cm5/configuration.nix
              ./hosts/uconsole-cm5/hardware-configuration.nix
            ];
          };
        };
        devShells.${system}.default = devShell;
      };
}